mocninne_rady.mws

Nekonecne rady s programem Maple

Mocninne rady

Karel Srot, xsrot@math.muni.cz

>   

>    currentdir("c:/devel/maple/phd/export/"):

>   

Obor konvergence

>    restart:

>    read "posl_a_rady_fci_proc.mpl":

>   

Priklad 1:

Naleznete obor konvergence mocninne rady  

  Sum((-1)^n*(x+2)^n/(n+sqrt(n)),n = 1 .. infinity)  

>    an:=n->(-1)^n/(n+sqrt(n));

an := n -> (-1)^n/(n+sqrt(n))

>    simplify(an(n)/an(n+1));

-1/(n+n^(1/2))*(n+1+(n+1)^(1/2))

>    r:=limit(abs(%), n=infinity);

r := 1

>    csum(subs(x=-3, an(n)), n);

true

>    csum(subs(x=-1, an(n)), n);

true

Oborem konvergence je tedy interval [-3,-1].

>   

>   

Priklad 2:

Urcete obor konvergence mocninne rady

   Sum((1+1/n)^(n^2),n = 1 .. infinity)  

 

>    an:=n->(1+1/n)^(n^2);

an := n -> (1/n+1)^(n^2)

>    simplify(1/abs(an(n))^(1/n));

abs(((n+1)/n)^(n^2))^(-1/n)

>    r:=limit(%, n=infinity);

r := exp(-1)

>    csum(subs(x=-r, an(n)), n);

false

>    csum(subs(x=r, an(n)), n);

false

Oborem konvergence je interval ( -1/e. 1/e ) .

>   

>   

>    infolevel[sum]:=2:

>    infolevel[TestSeriesConvergence]:=2:

>   

Priklad 3:

Urcete polomer konvergence a soucet mocninne rady

  Sum(2^n*x^(2*n),n = 0 .. infinity)    

>    an:=(n,x)->2^n*x^(2*n);

an := (n, x) -> 2^n*x^(2*n)

>    TestSeriesConvergence(an(n,x),n,x); 

TestSeriesConvergence:   Series identical zero when    x   =   0

TestSeriesConvergence:   Trying ration test

TestSeriesConvergence:   Limit:   2*x^2

TestSeriesConvergence:   Range solved:   RealRange(Open(-1/2*2^(1/2)),Open(1/2*2^(1/2)))

TestSeriesConvergence:   Checking isolated points

TestSeriesConvergence:   Diverges at point   x   =   1/2*2^(1/2)

TestSeriesConvergence:   Diverges at point   x   =   -1/2*2^(1/2)

RealRange(Open(-1/2*2^(1/2)),Open(1/2*2^(1/2)))

>    sum(an(n,x),n=0..infinity); 

convert/hypergeom/from:   Function    2^x*x^(2*x)    satisfies the criteria

-1/(2*x^2-1)

>   

Priklad :

Urcete obor konvergence mocninne rady

   Sum(2^n*x^n/(n^2),n = 1 .. infinity)

 

>    an:=(n,x)->2^n*x^n/n^2;

an := (n, x) -> 2^n*x^n/n^2

>    TestSeriesConvergence(an(n,x),n,x); 

TestSeriesConvergence:   Series identical zero when    x   =   0

TestSeriesConvergence:   Trying ration test

TestSeriesConvergence:   Limit:   2*abs(x)

TestSeriesConvergence:   Range solved:   RealRange(Open(-1/2),Open(1/2))

TestSeriesConvergence:   Checking isolated points

TestSeriesConvergence:   Converges at point   x   =   -1/2

TestSeriesConvergence:   Converges at point   x   =   1/2

RealRange(-1/2,1/2)

>   

Priklad:

Urcete obor konvergence a soucet mocninne rady

   Sum((-1)^(n+1)*x^(n+1)/(n*(n+1)),n = 1 .. infinity)  

>    an:=(n,x)->(-1)^(n+1)*(x^(n+1))/(n*(n+1));

an := (n, x) -> (-1)^(n+1)*x^(n+1)/n/(n+1)

>    sum(an(n,x),n=1..infinity); 

convert/hypergeom/from:   Function    -(-1)^(x+1)*x^(x+2)/(x+1)/(x+2)    satisfies the criteria

ln(x+1)*x+ln(x+1)-x

>    TestSeriesConvergence(an(n,x),n,x); 

TestSeriesConvergence:   Series identical zero when    x   =   0

TestSeriesConvergence:   Trying ration test

TestSeriesConvergence:   Limit:   abs(x)

TestSeriesConvergence:   Range solved:   RealRange(Open(-1),Open(1))

TestSeriesConvergence:   Checking isolated points

TestSeriesConvergence:   Converges at point   x   =   -1

TestSeriesConvergence:   Converges at point   x   =   1

RealRange(-1,1)

>   

>   

Priklad:

Urcete obor konvergence mocninne rady

Sum(n!^2*x^n/(2*n)!,n = 1 .. infinity)    

>    an:=(n,x)->(n!)^2*x^n/(2*n)!;

an := (n, x) -> n!^2*x^n/(2*n)!

>    TestSeriesConvergence(an(n,x),n,x); 

TestSeriesConvergence:   Series identical zero when    x   =   0

TestSeriesConvergence:   Trying ration test

TestSeriesConvergence:   Limit:   1/4*abs(x)

TestSeriesConvergence:   Range solved:   RealRange(Open(-4),Open(4))

TestSeriesConvergence:   Checking isolated points

TestSeriesConvergence:   Diverges at point   x   =   -4

TestSeriesConvergence:   Diverges at point   x   =   4

RealRange(Open(-4),Open(4))

>   

>   

soucet mocninne rady

>    restart:

>    read "posl_a_rady_fci_proc.mpl":

>   

Priklad:

Urcete soucet mocninne rady

  Sum(x^(4*n-3)/(4*n-3),n = 1 .. infinity)    

>    an:=(n,x)->x^(4*n-3)/(4*n-3);

an := (n, x) -> x^(4*n-3)/(4*n-3)

>    TestSeriesConvergence(an(n,x),n,x);

RealRange(Open(-1),Open(1))

>    assume(x::RealRange(Open(-1),Open(1)));

pokusime se ziskat soucet rady pomoci procedury sum().

>    sum(an(n,x),n=1..infinity);

1/4*x*LerchPhi(x^4,1,1/4)

>    ?LerchPhi

>    Sum(an(n,x),n=1..infinity);

Sum(x^(4*n-3)/(4*n-3),n = 1 .. infinity)

>    diff(%,x);

Sum(x^(4*n-3)/x,n = 1 .. infinity)

>    simplify(%);

Sum(x^(4*n-4),n = 1 .. infinity)

>    s1:=value(%);

s1 := -1/(x^4-1)

>    s2:=subs(x=t,s1);

s2 := -1/(t^4-1)

>    int(s2,t=0..x);

1/2*arctanh(x)+1/2*arctan(x)

>    r:=int(s2,t);

r := 1/2*arctanh(t)+1/2*arctan(t)

>    r:=convert(op(1,r),ln)+op(2,r);

r := 1/4*ln(t+1)-1/4*ln(1-t)+1/2*arctan(t)

>    eval(r,t=x)- eval(r,t=0);

1/4*ln(x+1)-1/4*ln(1-x)+1/2*arctan(x)

dalsi moznost vypoctu pomoci parcialnich zlomku:

>    convert(s2,parfrac);

-1/(4*(t-1))+1/(2*(t^2+1))+1/(4*(t+1))

>    int(%,t);

-1/4*ln(t-1)+1/2*arctan(t)+1/4*ln(t+1)

>    r:=eval(%,t=x)-eval(%,t=0);

r := -1/4*ln(x-1)+1/2*arctan(x)+1/4*ln(x+1)+1/4*I*Pi

>    evalc(Re(r));

1/4*ln(x+1)-1/4*ln(1-x)+1/2*arctan(x)

>    evalc(Im(r));

0

>   

rozvoj funkce do mocninne rady

>    restart;

>    read "posl_a_rady_fci_proc.mpl":

>   

Priklad:

Urcete Taylorovy polynomy stupnu 1, 3, 5 funkce y = exp(x/2)  se stredem v bode x[0] = 1  .

>    f:=exp(x/2):

>    x0:=1:

>   

>    taylor(f,x=1,2);

series(exp(1/2)+1/2*exp(1/2)*(x-1)+O((x-1)^2),x=-(-1),2)

>    convert(%, polynom);

exp(1/2)+1/2*exp(1/2)*(x-1)

>    convert(taylor(f,x=1,4), polynom);

exp(1/2)+1/2*exp(1/2)*(x-1)+1/8*exp(1/2)*(x-1)^2+1/48*exp(1/2)*(x-1)^3

>    convert(taylor(f,x=1,6), polynom);

exp(1/2)+1/2*exp(1/2)*(x-1)+1/8*exp(1/2)*(x-1)^2+1/48*exp(1/2)*(x-1)^3+1/384*exp(1/2)*(x-1)^4+1/3840*exp(1/2)*(x-1)^5

>    coeftayl(f,x=1,3);

1/48*exp(1/2)

>   

Priklad:

Urcete Tayloruv polynom stupne deset funkce y = exp(-x^2)  se stredem v bode x[0] = 0  .

>    f:=exp(-x^2);

f := exp(-x^2)

>    convert(taylor(f,x,11), polynom);

1-x^2+1/2*x^4-1/6*x^6+1/24*x^8-1/120*x^10

>   

Priklad:

Rozvinte funkci y = exp(2*x)   do mocninne rady a urcite obor konvergence.

>    convert(exp(2*x),Sum);

Sum((2*x)^_k1/_k1!,_k1 = 0 .. infinity)

>    subs(_k1=k,%);

Sum((2*x)^k/k!,k = 0 .. infinity)

>    an:=(n,x)->(2*x)^n/n!;

an := (n, x) -> (2*x)^n/n!

>    TestSeriesConvergence(an(n,x),n,x);

real

Priklad:

Rozvinte funkci ln(1+x) do mocninne rady a urcete obor konvergence.

>    convert(ln(1+x),Sum);

ln(1+x)

Prislusna mocninna rada neni konvergentni na celem definicnim oboru funkce ln(1+x).

>    FunctionAdvisor( sum_form, ln(x+1));

[ln(1+x) = x*Sum((-x)^_k1/(1+_k1),_k1 = 0 .. infinity), And(abs(x) < 1)]

>    assume(x::RealRange(Open(-1),Open(1)));

>    convert(ln(x+1),Sum);

x*Sum((-x)^_k1/(1+_k1),_k1 = 0 .. infinity)

>    an:=(n,x)->x*(-x)^n/(1+n);

an := (n, x) -> x*(-x)^n/(1+n)

>    TestSeriesConvergence(an(n,x) ,n,x);

RealRange(Open(-1),1)

>   

>   

Animace mocninnych rozvoju

>    restart;

>    read "posl_a_rady_fci_proc.mpl":

>   

Priklad:

Animaci znazornete konvergenci Maclaurinova rozvoje funkce y=sin(x).

>    f:=x->sin(x):

>    fn:=(n,x)->convert(taylor(f(x),x,n+1), polynom):

>    fn(5,x);

x-1/6*x^3+1/120*x^5

>    graf_fce:=plot(f,-10..10,thickness=2, color=green):

>    graf:=n->plots[display](graf_fce,plot(fn(n,x),x=-10..10,y=-5..5,thickness=2)):

>    plots[display](seq(graf(i),i=0..19), insequence=true,scaling=constrained);

[Maple Plot]

>   

>   

Priklad:

Animaci znazornete konvergenci Taylorova rozvoje se stredem v bode x=1 funkce

  y = sqrt(1+1/x)  .

>    f:=x->sqrt(1+1/x);

f := x -> sqrt(1+1/x)

>    fn:=(n,x)->convert(taylor(f(x),x=1,n+1), polynom):

>    fn(5,x);

2^(1/2)-1/4*2^(1/2)*(x-1)+7/32*2^(1/2)*(x-1)^2-25/128*2^(1/2)*(x-1)^3+363/2048*2^(1/2)*(x-1)^4-1335/8192*2^(1/2)*(x-1)^5

>    graf_fce:=plot(f,-2..4,thickness=2, color=green):

>    graf:=n->plots[display](plot(fn(n,x),x=-2..4,y=0..5,thickness=2),graf_fce):

>    plots[display](seq(graf(i),i=0..19), insequence=true,scaling=constrained);

[Maple Plot]

>   

>   

Priklad:

Pomoci animace znazornete konvergenci mocninne rady

  Sum((-1)^(n+1)*x^(n+1)/(n*(n+1)),n = 1 .. infinity)   

>    fn:=(n,x)->(-1)^(n+1)*(x^(n+1))/(n*(n+1)):

>    TestSeriesConvergence(fn(n,x),n,x);

RealRange(-1,1)

>    s:=sum(fn(n,x),n=1..infinity);

s := ln(x+1)*x+ln(x+1)-x

>    sn:=(n,x)->sum(fn(k,x),k=1..n):

>   

>    graf_s:=plot(s,x=-1..1,color=green,thickness=3):

>    pruh:=plotVerticalStrip(RealRange(-1,1),-0.5..1.5):

>    graf:=n->plots[display](pruh, plot(sn(n,x),x=-2..2, y=-0.5..1.5,
 thickness=2), graf_s):

>    plots[display](seq(graf(i),i=1..15), insequence=true,
 scaling=constrained);

[Maple Plot]

>   

>